% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            arabic_verbs.dtr                                         %
% Purpose:         to describe Arabic verb inflection                       %
% Author:          Lynne Cahill                                             %
%                  L.Cahill@brighton.ac.uk                                  %
%                                                                           %
%      Copyright (c) University of Brighton 2010.  All rights reserved.     %
%           Contents of this file covered by GNU public licence             %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% choose show statement file:
%   1. binyan 1 only or all binyanim
%   2. active, passive or all
%   3. stems only
%
%# load 'show_bin1_act.dtr'.
%# load 'show_bin1_pass.dtr'.
%# load 'show_bin1_all.dtr'.
%# load 'show_allbin_act.dtr'.
%# load 'show_allbin_pass.dtr'.
# load 'show_allbin_all.dtr'.
%# load 'show_stems.dtr'.

% choose verb lexeme entry file:
%   1. "write" only
%   2. individual weak verbs
%   3. all strong verbs
%   4. all weak and strong verbs
%# load 'write.dtr'.  %strong
%# load 'throw.dtr'.  %naaqis
%# load 'arrive.dtr'. %mithal
%# load 'visit.dtr'.  %ajwaf
%# load 'strong_verbs.dtr'.
%# load 'weak_verbs.dtr'.
# load 'all_verbs.dtr'.

% load weak verb checks:
# load 'weak_checks.dtr'.

# uses Qpath.

% The structure of syllables and syllable sequences (same as for English etc.)

# vars $yll: syl1 syl2 syl3.
# vars $voice: act pass.
# atom T.
Null:
    <> == .

Syllable:
    <> == Null
    <phn root>  == <phn syl1>

    <phn $yll form>  == "<phn $yll onset>" "<phn $yll rhyme>"
    <phn $yll rhyme> == "<phn $yll peak>"  "<phn $yll coda>"
    <phn $yll coda>  == "<phn $yll body>"  "<phn $yll tail>".

Disyllable:
    <> == Syllable
    <phn root>  == <phn syl2> <phn syl1>.

Trisyllable:
    <> == Syllable
    <phn root>  == <phn syl3> <phn syl2> <phn syl1>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# vars $pers: first secnd third.
# vars $pers-1: secnd third.
# vars $12pers: first secnd.
# vars $num: sing dual plur.
# vars $num-pl: sing dual.

% The (default) structure of affixes and words

Affix:
    <> == Syllable.

Word:
    <> == Syllable

    <mor word> == "<phn root form>" "<mor suffix>".

Verb:
    <> == Disyllable
    <mor word> == "<agr prefix>" "<tense prefix>"
                  "<phn root form>" "<agr suffix>"

    % basic root structure
    <phn syl2 onset> == Qpath:<c1>
    <phn syl2 onset pres> == Cwm:<Qpath:<c1>>
    <phn syl2 onset pres pass> == Cwmp:<Qpath:<c1>>
    <phn syl1 onset> == Cwac:<Qpath:<c2>>
    <phn syl1 coda> == Qpath:<c3>
    <phn syl1 coda pres>  == Cwnc1:<Qpath:<c3>>
    <phn syl1 coda past $voice third>  == Cwnc2:<Qpath:<c3>
                                        "<agr suffix past $voice third>">

    <phn syl2 peak> == a
    <phn syl1 peak> == a

    % default vowels for different tenses
    <phn syl2 peak past act $12_pers> == Cwav2:<Qpath:<c2>>
    <phn syl2 peak past act third> == a
    <phn syl2 peak past act third plur femn> == Cwav2:<Qpath:<c2>>
    <phn syl2 peak past pass> == Cwav1:<Qpath:<c2>>
    <phn syl1 peak past act $12_pers> == Cwav3:<Qpath:<c2>>
    <phn syl1 peak past act third> == a
    <phn syl1 peak past act third plur femn> == Cwav3:<Qpath:<c2>>
    <phn syl1 peak past pass> == i
    <phn syl1 peak past pass third plur masc> == Cwnv:<Qpath:<c3>>
    <phn syl1 peak pres act> == i
    <phn syl1 peak pres pass> == Cwnav:<Qpath:<c2> Qpath:<c3>>
    <phn syl1 peak part act> == i

    % prefixes for different tenses
    <tense prefix pres act> == a
    <tense prefix pres pass> == u

    <tense prefix part> == m u

    % mapping different binyan forms to binyan nodes (could be abbreviated).
    <bin1> == "Bin1:<>"
    <bin2> == "Bin2:<>"
    <bin3> == "Bin3:<>"
    <bin4> == "Bin4:<>"
    <bin5> == "Bin5:<>"
    <bin6> == "Bin6:<>"
    <bin7> == "Bin7:<>"
    <bin8> == "Bin8:<>"
    <bin9> == "Bin9:<>"
    <bin10> == "Bin10:<>"
    <bin11> == "Bin11:<>"
    <bin12> == "Bin12:<>"
    <bin13> == "Bin13:<>"
    <bin14> == "Bin14:<>"
    <bin15> == "Bin15:<>"

% person/number inflections - past tense has suffix only, present tense has
% prefix and suffix.

    <agr prefix pres $voice> == t
    <agr prefix pres $voice first sing> ==
    <agr prefix pres $voice first plur> == n
    <agr prefix pres $voice third> == j
    <agr prefix pres $voice third $num-pl femn> == t
    <agr prefix pres $voice third femn> == t

    <agr suffix pres $voice> == Cwnsv:<$voice Qpath:<c3>>
    <agr suffix pres $voice $pers dual> == 'a:' n i
    <agr suffix pres $voice $pers-1 plur masc> == Cwnsu:<$voice Qpath:<c3>>
    <agr suffix pres $voice secnd sing femn> == Cwnsi:<$voice Qpath:<c3>>
    <agr suffix pres $voice $pers-1 plur femn> == Cwnsn:<$voice Qpath:<c3>>
    <agr suffix past $voice first sing> == t u
    <agr suffix past $voice first plur> == n 'a:'
    <agr suffix past $voice secnd sing masc> == t a
    <agr suffix past $voice secnd sing femn> == t i
    <agr suffix past $voice secnd dual> == t u m 'a:'
    <agr suffix past $voice secnd plur masc> == t u m
    <agr suffix past $voice secnd plur femn> == t u n n a
    <agr suffix past $voice third sing masc> == a
    <agr suffix past $voice third sing femn> == Cwnsa:<Qpath:<c3>>
    <agr suffix past $voice third dual masc> == 'a:'
    <agr suffix past $voice third dual femn> == a t 'a:'
    <agr suffix past $voice third plur masc> == Cwnsuu:<$voice Qpath:<c3>>
    <agr suffix past $voice third plur femn> == n a
.

% Binyan I - the most basic and with the most "irregularities"
Bin1:
    <> == Verb
    <phn syl2 coda pres act> == "<c1>"
    <phn syl1 peak pres act> == Cwnmas:<Qpath:<c1> Qpath:<c2> Qpath:<c3>>
    <phn syl2 peak pres> ==
    <phn syl2 peak part pass> ==
    <phn syl2 peak part act> == a a
    <phn syl1 peak part pass> == u u
    <tense prefix part act> ==
    <tense prefix part pass> == m a
.

% Binyan II - doubled middle consonant, one prefix difference
Bin2:
    <> == Verb
    <phn syl2 coda> == Qpath:<c2>
    <tense prefix pres act> == u.

% Binyan III - doubled first vowel, prefix difference as above
Bin3:
    <> == Verb
    <phn syl2 peak> == Verb Verb
    <tense prefix pres act> == Bin2.

% Binyan IV - c1 moved and /?/ added in its place, prefix as above
Bin4:
    <> == Verb
    <phn syl2 onset> == '?'
    <phn syl2 coda> == Qpath:<c1>
    <tense prefix pres act> == Bin2.

% Binyan V - trisyllable, has extra syllable's values defined, different final
% peak, consonant doubling as for Bin II.
Bin5:
    <> == Verb
    <phn root> == Trisyllable
    <phn syl3 onset> == t
    <phn syl3 peak> == "<phn syl2 peak>"
    <phn syl1 peak pres act> == a
    <phn syl2 coda> == Bin2.

% Binyan VI - as Bin V but no consonant doubling, first peak fixed, second
% doubled as Bin III.
Bin6:
    <> == Bin5
    <phn syl2 coda> == Verb
    <phn syl3 peak> == a
    <phn syl3 peak past pass> == u
    <phn syl2 peak> == Bin3.

% Binyan VII - trisyllable, coda only defined for first syllable
Bin7:
    <> == Verb
    <phn root> == Trisyllable
    <phn syl3 coda> == n.

% Binyan VIII - adds second consonant to first onset.
Bin8:
    <> == Verb
    <phn syl2 onset> == Verb Qpath:<c2>.

% Binyan IX - as Bin VIII but second coda is third, not second, consonant
Bin9:
    <> == Bin8
    <phn syl1 onset> == Qpath:<c3>.

% Binyan X - as Bin VI, but with /st/ in place of first consonant
Bin10:
    <> == Bin4
    <phn syl2 onset> == s t
    <tense prefix pres act> == Verb.

% Binyan XI - as Bin IX, but vowel doubled as in Bin III
Bin11:
    <> == Bin9
    <phn syl2 peak> == Bin3.

% Binyan XII - as Bin VIII, first coda /w/
Bin12:
    <> == Bin8
    <phn syl2 coda> == w.

% Binyan XIII - as Bin XII, second onset also /w/
Bin13:
    <> == Bin12
    <phn syl1 onset> == w.

% Binyan XIV - as Bin IX, first coda /n/
Bin14:
    <> == Bin9
    <phn syl2 coda> == n.

% Binyan XV - as Bin XIV, final consonant /j/
Bin15:
    <> == Bin14
    <phn syl1 coda> == j.

# hide
       Null Syllable Disyllable Trisyllable Affix Word Verb Bin1 Bin2 Bin3
       Bin4 Bin5 Bin6 Bin7 Bin8 Bin9 Bin10 Bin11 Bin12 Bin13 Bin14 Bin15
       .